提出 #6107568

---

ソースコード 拡げる

;; -*- coding: utf-8 -*-
(eval-when (:compile-toplevel :load-toplevel :execute)
  (defparameter OPT
    #+swank '(optimize (speed 3) (safety 2))
    #-swank '(optimize (speed 3) (safety 0) (debug 0)))
  #+swank (progn (ql:quickload '(:cl-debug-print :fiveam))
                 (shadow :run)
                 (use-package :fiveam))
  #-swank (set-dispatch-macro-character #\# #\> (lambda (s c p) (declare (ignore c p)) (read s nil (values) t))))
#+swank (cl-syntax:use-syntax cl-debug-print:debug-print-syntax)

;; BEGIN_INSERTED_CONTENTS
(defmacro with-output-buffer (&body body)
  "Buffers all outputs to *STANDARD-OUTPUT* in BODY and flushes them to
*STANDARD-OUTPUT* after BODY has been done (without error). Note that only
BASE-CHAR is allowed."
  (let ((out (gensym)))
    `(let ((,out (make-string-output-stream :element-type 'base-char)))
       (let ((*standard-output* ,out))
         ,@body)
       (write-string (get-output-stream-string ,out)))))

(declaim (ftype (function * (values fixnum &optional)) read-fixnum))
(defun read-fixnum (&optional (in *standard-input*))
  (declare #.OPT)
  (macrolet ((%read-byte ()
               `(the (unsigned-byte 8)
                     #+swank (char-code (read-char in nil #\Nul))
                     #-swank (sb-impl::ansi-stream-read-byte in nil #.(char-code #\Nul) nil))))
    (let* ((minus nil)
           (result (loop (let ((byte (%read-byte)))
                           (cond ((<= 48 byte 57)
                                  (return (- byte 48)))
                                 ((zerop byte) ; #\Nul
                                  (error "Read EOF or #\Nul."))
                                 ((= byte #.(char-code #\-))
                                  (setf minus t)))))))
      (declare ((integer 0 #.most-positive-fixnum) result))
      (loop
        (let* ((byte (%read-byte)))
          (if (<= 48 byte 57)
              (setq result (+ (- byte 48) (* 10 (the (integer 0 #.(floor most-positive-fixnum 10)) result))))
              (return (if minus (- result) result))))))))

;;;
;;; Rolling hash
;;;

;; TODO: handle multiple moduli together
(defstruct (rhash (:constructor %make-rhash (divisor cumul powers)))
  (divisor 1000000007 :type (unsigned-byte 32))
  (cumul nil :type (simple-array (unsigned-byte 32) (*)))
  (powers nil :type (simple-array (unsigned-byte 32) (*))))

(defun make-rhash (vector divisor &key (key #'char-code) base)
  "Returns the table of rolling-hash of VECTOR modulo DIVISOR. KEY is applied to
  each element of VECTOR prior to computing the hash value.

DIVISOR := unsigned 32-bit prime number
BASE := 1 | 2 | ... | DIVISOR - 1
KEY := function returning FIXNUM"
  (declare #.OPT
           (vector vector)
           ((unsigned-byte 32) divisor)
           ((or null (unsigned-byte 32)) base)
           (function key))
  (assert (sb-int:positive-primep divisor))
  (let* ((base (or base (+ 1 (random (- divisor 1)))))
         (size (length vector))
         (cumul (make-array (+ 1 size) :element-type '(unsigned-byte 32)))
         (powers (make-array (+ 1 size) :element-type '(unsigned-byte 32))))
    (assert (<= 1 base (- divisor 1)))
    (setf (aref powers 0) 1)
    (dotimes (i size)
      (setf (aref powers (+ i 1))
            (mod (* (aref powers i) base) divisor))
      (let ((sum (+ (mod (* (aref cumul i) base) divisor)
                    (mod (the fixnum (funcall key (aref vector i))) divisor))))
        (setf (aref cumul (+ i 1))
              (if (> sum divisor)
                  (- sum divisor)
                  sum))))
    (%make-rhash divisor cumul powers)))

(declaim (inline rhash-query)
         (ftype (function * (values (unsigned-byte 32) &optional)) rhash-query))
(defun rhash-query (rhash l r)
  "Returns the hash value of the interval [L, R)."
  (declare ((integer 0 #.most-positive-fixnum) l r))
  (assert (<= l r))
  (let ((cumul (rhash-cumul rhash))
        (powers (rhash-powers rhash))
        (divisor (rhash-divisor rhash)))
    (let ((res (+ (aref cumul r)
                  (- divisor (mod (* (aref cumul l) (aref powers (- r l))) divisor)))))
      (if (> res divisor)
          (- res divisor)
          res))))

(declaim (inline rhash-concat))
(defun rhash-concat (rhash hash1 hash2 hash2-length)
  (declare ((unsigned-byte 32) hash1 hash2)
           ((integer 0 #.most-positive-fixnum) hash2-length))
  (let* ((divisor (rhash-divisor rhash)))
    (mod (+ hash2
            (mod (* hash1
                    (aref (rhash-powers rhash) hash2-length))
                 divisor))
         divisor)))

(declaim (inline rhash-get-lcp))
(defun rhash-get-lcp (rhash1 start1 rhash2 start2)
  (declare ((integer 0 #.most-positive-fixnum) start1 start2))
  (assert (= (rhash-divisor rhash1) (rhash-divisor rhash2)))
  (assert (and (< start1 (length (rhash-cumul rhash1)))
               (< start2 (length (rhash-cumul rhash2)))))
  (let ((max-length (min (- (length (rhash-cumul rhash1)) start1 1)
                         (- (length (rhash-cumul rhash2)) start2 1))))
    (if (= (rhash-query rhash1 start1 (+ start1 max-length))
           (rhash-query rhash2 start2 (+ start2 max-length)))
        max-length
        (labels ((bisect (ok ng)
                   (declare ((integer 0 #.most-positive-fixnum) ok ng))
                   (if (<= (- ng ok) 1)
                       ok
                       (let ((mid (ash (+ ng ok) -1)))
                         (if (= (rhash-query rhash1 start1 (+ start1 mid))
                                (rhash-query rhash2 start2 (+ start2 mid)))
                             (bisect mid ng)
                             (bisect ok mid))))))
          (bisect 0 max-length)))))

(defmacro dbg (&rest forms)
  #+swank
  (if (= (length forms) 1)
      `(format *error-output* "~A => ~A~%" ',(car forms) ,(car forms))
      `(format *error-output* "~A => ~A~%" ',forms `(,,@forms)))
  #-swank (declare (ignore forms)))

(defmacro define-int-types (&rest bits)
  `(progn
     ,@(mapcar (lambda (b) `(deftype ,(intern (format nil "UINT~A" b)) () '(unsigned-byte ,b))) bits)
     ,@(mapcar (lambda (b) `(deftype ,(intern (format nil "INT~A" b)) () '(signed-byte ,b))) bits)))
(define-int-types 2 4 7 8 15 16 31 32 62 63 64)

(declaim (inline println))
(defun println (obj &optional (stream *standard-output*))
  (let ((*read-default-float-format* 'double-float))
    (prog1 (princ obj stream) (terpri stream))))

(defconstant +mod+ 1000000007)

;; Body

(declaim (ftype (function * (values uint32 &optional)) concat))
(defun concat (rhash l r pos char)
  (declare #.OPT (uint32 l r pos))
  (assert (<= l r))
  (if (and (<= l pos) (< pos r))
      (rhash-concat rhash
                    (rhash-concat rhash (rhash-query rhash l pos) (char-code char) 1)
                    (rhash-query rhash (+ pos 1) r)
                    (- r pos 1))
      (rhash-query rhash l r)))

(defun main ()
  (declare #.OPT)
  (let* ((s (coerce (read-line) 'simple-base-string))
         (q (read))
         (rhash1 (make-rhash s 1000000007))
         (rhash2 (make-rhash s 1000000009)))
    (declare (uint32 q)
             (simple-base-string s))
    (with-output-buffer
      (dotimes (i q)
        (let* ((l (- (read-fixnum) 1))
               (r (read-fixnum))
               (period (read-fixnum))
               (lcp (min (rhash-get-lcp rhash1 l rhash1 (+ l period))
                         (rhash-get-lcp rhash2 l rhash2 (+ l period)))))
          (declare (uint32 l r period lcp))
          ;; #>lcp
          (if (or (>= lcp (- r l period))
                  (and (= (concat rhash1 l (- r period) (+ l lcp) (aref s (+ l period lcp)))
                          (concat rhash1 (+ l period) r (+ l lcp) (aref s (+ l period lcp))))
                       (= (concat rhash2 l (- r period) (+ l lcp) (aref s (+ l period lcp)))
                          (concat rhash2 (+ l period) r (+ l lcp) (aref s (+ l period lcp)))))
                  (and (= (concat rhash1 l (- r period) (+ l period lcp) (aref s (+ l lcp)))
                          (concat rhash1 (+ l period) r (+ l period lcp) (aref s (+ l lcp))))
                       (= (concat rhash2 l (- r period) (+ l period lcp) (aref s (+ l lcp)))
                          (concat rhash2 (+ l period) r (+ l period lcp) (aref s (+ l lcp))))))
              (write-line "Yes")
              (write-line "No")))))))

#-swank(main)

提出情報

ジャッジ結果