提出 #33960576

---

ソースコード 拡げる

import Control.Monad
import qualified Data.ByteString.Char8 as BS
import Data.Char
import Data.List

import Data.Array

main = do
  [n] <- bsGetLnInts
  [sx,sy,tx,ty] <- bsGetLnInts
  xyrs <- replicateM n bsGetLnInts
  let ans = abc259d n sx sy tx ty xyrs
  putStrLn $ if ans then "Yes" else "No"

bsGetLnInts :: IO [Int]
bsGetLnInts = BS.getLine >>= return . unfoldr (BS.readInt . BS.dropWhile isSpace)

abc259d :: Int -> Int -> Int -> Int -> Int -> [[Int]] -> Bool
abc259d n sx sy tx ty xyrs = findUF uf a b
  where
    a = findab sx sy xyrs
    b = findab tx ty xyrs
    uf = foldl (\uf (i,j) -> uniteUF uf i j) (newUF n)
      [ (i,j)
      | (i,c1) : jcs <- tails (zip [0..] xyrs)
      , (j,c2)       <- jcs
      , connect c1 c2]

findab x y xyrs = head
  [i | (i, (xi:yi:ri:_)) <- zip [0..] xyrs, dist2 x y xi yi == ri^2]

dist2 x1 y1 x2 y2 = (x1 - x2)^2 + (y1 - y2)^2

connect (x1:y1:r1:_) (x2:y2:r2:_)
  | (max r1 r2)^2 <= d2 = (r1 + r2)^2 >= d2
  | otherwise           = (r1 - r2)^2 <= d2
  where
    d2 = dist2 x1 y1 x2 y2

-- UnionFind
type UnionFind = Array Int Int

-- 0からN-1までのN要素が独立した初期状態を作る
newUF :: Int -> UnionFind
newUF n = listArray (0, pred n) $ replicate n (-1)

-- 補助関数 ノードの根まで辿り、そのrank（負）と共に返す
getRoot :: UnionFind -> Int -> (Int, Int)
getRoot uf i = let k = uf ! i in if k < 0 then (i, k) else getRoot uf k

-- ふたつのノードが同じ分割に属しているか判定する
findUF :: UnionFind -> Int -> Int -> Bool
findUF uf i j = fst (getRoot uf i) == fst (getRoot uf j)

-- ふたつのノードが同じ分割に属していることを登録する
uniteUF :: UnionFind -> Int -> Int -> UnionFind
uniteUF uf i j
  | a == b = uf
  | otherwise =
      case compare r s of
        GT -> uf // [(a,b)]
        LT -> uf // [(b,a)]
        EQ -> uf // [(b,a), (a, pred r)]
  where
    (a, r) = getRoot uf i
    (b, s) = getRoot uf j

提出情報

コンパイルエラー

Loaded package environment from /home/contestant/.ghc/x86_64-linux-8.8.3/environments/default

ジャッジ結果